At the moment we split our still images into a large amount of tiles (128-256ish).
To rerender a tile or region in jigsaw, I have to create from Tiles Grid, invert all the tiles it has made (which takes a good 2 minutes to do), deselect everything (takes a long time, as I can see it deselecting in the viewport 1 at a time) then go in and find the tiles I want to rerender and tick the box.
Is it possible for Jigsaw to pull in the user-defined tiles that have been selected under tile rendering, and just create regions based off those when creating from Tiles Grid?
Ideally, I would love to get this region tool Bobo sorted out in this thread (forums.thinkboxsoftware.com/vie … 11&t=15317), where I can just create the needed regions in the viewport (irrespective of tiles) and it would get passed to the SMTD and they would be loaded into the jigsaw region list.
I think selecting individual tiles might defeat the purpose of Jigsaw a little bit. Is there a reason you need to use the original tile layout as opposed to creating a new sub-region of the final frame?
I like the idea, but I’m not sure if it’s really needed if you’re only redoing a 1000x1000 chunk of the image. It’d just split the sub-image of the final frame into its own tiley grid.
Adding an option to the []CREATE From… menu to make only the selected user tiles is trivial:
First locate the menu definition and add a new option:
rcmenu MultiRegion_CreateFrom_Menu
(
menuItem mnu_createFromSceneSelection "Create From SCENE SELECTION..." enabled:(selection.count > 0)
menuItem mnu_createFromGrid "Create From TILES GRID..."
menuItem mnu_createFromGridUserTiles "Create From Tiles Grid USER TILES..." --NEW LINE
menuItem mnu_createFromMaxRegion "Create From 3DS MAX REGION..."
separator sep10
Then add the event handler:
on mnu_createFromMaxRegion picked do SMTD_MultiRegionRendering.createFromMaxRegion()
on mnu_createFromGrid picked do SMTD_MultiRegionRendering.createFromTilesGrid()
on mnu_createFromGridUserTiles picked do SMTD_MultiRegionRendering.createFromTilesGrid usertiles:true --NEW LINE
on mnu_createFromSceneSelection picked do
Finally, modify the actual createFromTilesGrid() function to add the usertiles option:
fn createFromTilesGrid usertiles:false = --NEW KEYWORD ARGUMENT
(
local result = if SMTDSettings.MultiRegionData.count == 0 then #no else (yesNoCancelBox ("Click [Yes] to REPLACE the Regions with a Grid of " + SMTDSettings.TilesInX as string + "x" + SMTDSettings.TilesInY as string + " Tiles.\nClick [No] to APPEND to the existing list.\nClick [Cancel] to do nothing.") title:"Replace Or Append Regions?")
case result of
(
#yes: (
createRegionGizmo false
removeMRManipulator()
SMTDSettings.MultiRegionData = #()
)
#cancel: return false
)
local cnt = 0
for y in 1 to SMTDSettings.TilesInY do
(
for x in 1 to SMTDSettings.TilesInX do
(
if usertiles == false or findItem SMTDSettings.CustomTiles [x,y] > 0 do --NEW IF STATEMENT
(
cnt +=1
append SMTDSettings.MultiRegionData #(true, 1.0*(x-1)/SMTDSettings.TilesInX, 1.0*(y-1)/SMTDSettings.TilesInY, 1.0/SMTDSettings.TilesInX, 1.0/SMTDSettings.TilesInY, 1, 1, SMTDSettings.TilesInX as string + "x"+ SMTDSettings.TilesInY as string+ " Grid Tile #" + cnt as string)
)
)
)
updateListView()
setListViewSelection (lastSelectedLines=#(1))
createMRManipulator()
createRegionGizmo true
updateToRegionGizmo()
updateSpinners()
updateEnabledStates()
if usertiles == true then --NEW IF STATEMENT FOR USER TILES UNDO RECORD
createUndoRecord ("Create "+SMTDSettings.CustomTiles.count as string+" User Regions From "+SMTDSettings.TilesInX as string + "x" + SMTDSettings.TilesInY as string+ " Tiles Grid")
else
createUndoRecord ("Create Regions From "+SMTDSettings.TilesInX as string + "x" + SMTDSettings.TilesInY as string+ " Tiles Grid")
)
Make these changes to your SubmitMaxToDeadline.ms file under the Repository\Submission\3dsmax\Main, save the file, and restart SMTD. You should not have the exact workflow you asked for.
However, you could simply submit in TILE mode with Use Custom Tiles checked instead of going through Jigsaw anyway. What is the reason to want to go through Jigsaw if you are doing a grid?
